**Adding an Elevator**

**By: Steven McMillan**

Well here is a way to script a very simple and basic lift that moves from point A to point B from a press of a button.   
  
For this to work you need to make script\_object with targetname "elevator" (without quotes) and a trigger\_use with targetname "elevator\_button" (again no quotes)  
  
The elevator works as the moving elevator platform, and the elevator\_button as a  a button, which player uses and activates the elevator.   
  
Remember tough that the trigger\_button will be invisible, so make a button out of brushes.   
  
  
main:   
  
level waittill prespawn   
  
thread elevator\_preparation //Set the threads...   
  
level waittill spawn   
  
end   
  
//----------------------------------------------------------->   
// Prepares the elvator by assigning the basic settings to it   
//----------------------------------------------------------->   
  
elevator\_preparation:   
  
$elevator moveto $waypoint\_down // Moves elevator to waypoint\_down.   
$elevator\_button bind $elevator // Attaches the elevator\_button into the elevator, this making it move same time as the elevator.   
$elevator time 4 // sets the elevator move time, 4 seconds in this case, could also use the command "speed".   
local.elepos = 0 // Defines the position of the elevator. "0 - lift down" "1 - lift up" Default - lift down   
goto elevator\_standby // standing by and waiting player to activate the trigger   
  
//----------------------------------------------------------->   
// Elevator is idle, and waiting user to activate the trigger   
//----------------------------------------------------------->   
  
elevator\_standby:   
  
$elevator\_button waittill trigger   
if (local.elepos == 0) // If lift state is down, its better get up.   
{   
println "elevator down - moving up" //prints this text to console if the developer mode is set.   
goto lift\_move\_up // jumps straight to the "lift\_move\_up" part in the script   
}   
else   
if (local.elepos == 1) // Or maybe lift state is up, and you need to get down?   
{   
println "elevator up - moving down" //prints this text to console if the developer mode is set.   
goto lift\_move\_down // jumps straight to the "lift\_move\_down" part in the script   
}   
  
//----------------------------------------------------------->   
  
lift\_move\_up:   
  
$elevator moveto $waypoint\_up //moves the lift to info\_waypoint with targetname waypoint\_up   
$elevator playsound elevator\_run //plays the "sound/mechanics/Mec\_ElevatorRun\_01.wav" defined in the ubersound.scr line 1052   
$elevator waitmove //wait till the elevator has completed the move before doing anything else   
local.elepos = 1 // it seems the elevator is up now, so we set the local.elepos to 1   
goto elevator\_standby // Jumps back to the standby part of the script waiting user to activate the trigger   
  
//----------------------------------------------------------->   
  
lift\_move\_down:   
  
$elevator moveto $waypoint\_down //moves the lift to info\_waypoint with targetname waypoint\_down   
$elevator playsound elevator\_run //plays the "sound/mechanics/Mec\_ElevatorRun\_01.wav" defined in the ubersound.scr line 1052   
$elevator waitmove //wait till the elevator has completed the move before doing anything else   
local.elepos = 0 // it seems the elevator is down now, so we set the local.elepos to 1   
goto elevator\_standby // Jumps back to the standby part of the script waiting user to activate the trigger   
  
//----------------------------------------------------------->   
  
end //the end.